1 REM: DATAMAKER        V2.0   13.1.84
2 REM: [C] HANS-JUERGEN KUTZ    JAN/84
3 POKE53280,12:POKE53281,12
4 OPEN1,0
5 PRINTCHR$(142)"[147][144]         * * * DATAMAKER * * *"
6 PRINT"            [C] JAN/1984 BY"
7 PRINT"           HANS-JUERGEN KUTZ"
8 PRINT
9 PRINT"           5100 AACHEN"
10 GOSUB49
11 PRINT"[147]DATAMAKER WANDELT EIN MASCHINENSPRACHE- PROGRAMM IN EIN BASIC-";
12 PRINT"LADEPROGRAMM UM."
13 PRINT"DIE VON DATAMAKER ERFRAGTE ZEILENNUMMER SOLLTE BEI GROESSEREN ODER ";
14 PRINT"MEHREREN ZU  UEBERSETZENDEN PROGRAMMEN MIT MAX.59000 ANGEGEBEN WERDEN."
15 FORI=1TO500:NEXT:GOSUB49
16 PRINT"[147][144]MIT WELCHER ZEILENNUMMER SOLLEN DIE     DATAZEILEN BEGINNEN ?"
17 LM=6:GOSUB50:Z=E:IFZ>63996ORZ<88THEN16
18 GOSUB61:Z=Z-1
19 PRINT"IN WELCHEM BEREICH LIEGT DAS MASCHINEN- PROGRAMM ?"
20 PRINT"BITTE DEZIMALE ANGABEN."
21 ZL=10:GOSUB67
22 ZE=10:SP=0:GOSUB68
23 PRINT"STARTADRESSE : ";
24 SP=15:GOSUB68
25 LM=6:GOSUB50:SA=E
26 IFSA>65535THEN21
27 ZL=12:GOSUB67
28 ZE=12:SP=0:GOSUB68
29 PRINT"ENDADRESSE   : ";
30 SP=15:GOSUB68
31 LM=6:GOSUB50:SE=E
32 IFSE<SAORSE>65535THEN27
33 T=INT((SE-SA)/16)+2
34 IFZ+T>63999THENPRINT"BITTE KLEINERE ZEILENNUMMER WAEHLEN.":GOTO13
35 GOSUB63:PRINTCHR$(147):S=SA:GOSUB71:A$=S$:S=SE:GOSUB71:E$=S$:GOSUB73
36 PRINT""Z"FORI="A$"TO"E$":READQ:POKEI,Q:NEXT":PRINT"GOTO37":GOTO85
37 GOSUB62:GOSUB65
38 N=SA+15:IFN>SETHENN=SE
39 GOSUB72
40 PRINT""Z"DATA"PEEK(SA)"[157]";:I=SA:GOSUB74:IFSA=NTHENPRINT:PRINT"GOTO45":GOTO42
41 FORI=SA+1TON:GOSUB74:S=PEEK(I):GOSUB71:PRINT","S$;:NEXT:PRINT:PRINT"GOTO43"
42 SA=I:GOSUB61:GOSUB63:GOTO85
43 GOSUB62:GOSUB65
44 IFSA<=SETHEN38
45 PRINT"[147][144]NOCH WEITERE UMWANDLUNGEN ?"
46 GETE$:IFE$<>"J"THENIFE$<>"N"THEN46
47 IFE$="J"THENGOSUB62:GOTO18
48 GOTO76
49 POKE198,0:WAIT203,63:RETURN
50 E=LM:EE$=""
51 POKE204,0:POKE198,0
52 WAIT198,255:WAIT207,1,1
53 GETE$
54 IFASC(E$)=20THENIFLEN(EE$)>0THENEE$=LEFT$(EE$,LEN(EE$)-1):E=E+1:PRINTE$;:GOTO52
55 IFASC(E$)=13THEN59
56 IFE$<"0"ORE$>"9"THEN52
57 PRINTE$;
58 EE$=EE$+E$:E=E-1:IFE>0THEN52
59 E=VAL(EE$):PRINT
60 WAIT207,1,1:POKE204,1:RETURN
61 POKE251,Z/256:POKE252,Z-256*PEEK(251)
62 Z=256*PEEK(251)+PEEK(252)+1:RETURN
63 POKE253,SA/256:POKE254,SA-256*PEEK(253)
64 POKE629,SE/256:POKE630,SE-256*PEEK(629)
65 SA=256*PEEK(253)+PEEK(254)
66 SE=256*PEEK(629)+PEEK(630):RETURN
67 POKE781,ZL:SYS59903:RETURN
68 IFZE>24THENZE=ZE-25:GOTO68
69 IFSP>39THENSP=SP-40:GOTO69
70 POKE214,ZE:POKE211,SP:SYS58732:RETURN
71 S$=RIGHT$(STR$(S),LEN(STR$(S))-1):RETURN
72 FORZL=0TO2:POKE781,ZL:SYS59903:NEXT
73 ZE=24:SP=20:GOSUB68:PRINT"[144]BITTE WARTEN.";:POKE646,PEEK(53281):RETURN
74 ZR=PEEK(214):SR=PEEK(211):ZE=10:SP=15:GOSUB68:PRINT"[144]"I:ZE=ZR:SP=SR:GOSUB68
75 POKE646,PEEK(53281):RETURN
76 POKE2,0:GOSUB72
77 N=PEEK(2)+1
78 POKE2,N:W=77
79 IFN=WTHENW=W+5
80 PRINT""N:PRINT"GOTO"W
81 GOTO84
82 N=PEEK(2):PRINT"[147]"N+1:PRINTN+2:PRINTN+3:PRINTN+4:PRINTN+5
83 PRINTN+6:PRINTN+7:PRINTN+8:PRINT"GOTO86"
84 POKE631,19:FORN=632TO640:POKEN,13:NEXT:POKE198,10:END
85 POKE631,19:POKE632,13:POKE633,13:POKE198,3:END
86 PRINT"[147]86":PRINT"87":PRINT"[144]LIST":POKE631,19:POKE632,13
87 POKE633,13:POKE634,13:POKE198,4:END